99热99这里只有精品6国产,亚洲中文字幕在线天天更新,在线观看亚洲精品国产福利片 ,久久久久综合网

歡迎加入QQ討論群258996829
麥子學(xué)院 頭像
蘋果6袋
6
麥子學(xué)院

u-boot啟動(dòng)流程是怎樣的

發(fā)布時(shí)間：2016-07-08 15:48  回復(fù):0  查看:4335   最后回復(fù)：2016-07-08 15:48  
本文將結(jié)合u-boot的“board—>machine—>arch—>cpu”框架， 教你 學(xué)習(xí)u-boot   中平臺(tái)相關(guān)部分的啟動(dòng)流程。并通過對(duì)啟動(dòng)流程的簡(jiǎn)單分析，掌握u-boot移植的基本方法。
平臺(tái)相關(guān)部分的啟動(dòng)流程分析
本文先不涉及 u-boot 和平臺(tái)相關(guān)的 Kconfig/Makefile 部分，以 ARM64 為例，假定 u-boot 首先從“ arch/arm/cpu/armv8/start.S” 的 _start 接口開始執(zhí)行。因此我們從 _start 開始分析。
注 3 ：后續(xù) u-boot 的移植指南中，會(huì)介紹該假定的依據(jù)。
注 4 ：?jiǎn)?dòng)流程分析的過程中，我們會(huì)重點(diǎn)解釋、歸納出代碼中以 CONFIG_ 為前綴的配置項(xiàng)，后續(xù) u-boot 的移植工作，大部分就是這些配置項(xiàng)的確定過程。
1 _start
_start 是 u-boot 啟動(dòng)后的第一個(gè)執(zhí)行地址，對(duì) armv8 來說，它只是簡(jiǎn)單的跳轉(zhuǎn)到 reset 處執(zhí)行，如下：
.globl        _start
_start:
        b        reset
2 reset
reset的代碼如下：
reset:
#ifdef CONFIG_SYS_RESET_SCTRL
        bl reset_sctrl
#endif
        /*
         * Could be EL3/EL2/EL1, Initial State:
         * Little Endian, MMU Disabled, i/dCache Disabled
         */
        adr        x0, vectors
        switch_el x1, 3f, 2f, 1f
3:        msr        vbar_el3, x0
        mrs        x0, scr_el3
        orr        x0, x0, #0xf                /* SCR_EL3.NS|IRQ|FIQ|EA */
        msr        scr_el3, x0
        msr        cptr_el3, xzr                /* Enable FP/SIMD */
#ifdef COUNTER_FREQUENCY
        ldr        x0, =COUNTER_FREQUENCY
        msr        cntfrq_el0, x0                /* Initialize CNTFRQ */
#endif
        b        0f
2:        msr        vbar_el2, x0
        mov        x0, #0x33ff
        msr        cptr_el2, x0                /* Enable FP/SIMD */
        b        0f
1:        msr        vbar_el1, x0
        mov        x0, #3 << 20
        msr        cpacr_el1, x0                /* Enable FP/SIMD */
0:
        /* Apply ARM core specific erratas */
        bl        apply_core_errata
        /*
         * Cache/BPB/TLB Invalidate
         * i-cache is invalidated before enabled in icache_enable()
         * tlb is invalidated before mmu is enabled in dcache_enable()
         * d-cache is invalidated before enabled in dcache_enable()
         */
        /* Processor specific initialization */
        bl        lowlevel_init
#ifdef CONFIG_ARMV8_MULTIENTRY
        branch_if_master x0, x1, master_cpu
        /*
         * Slave CPUs
         */
slave_cpu:
        wfe
        ldr        x1, =CPU_RELEASE_ADDR
        ldr        x0, [x1]
        cbz        x0, slave_cpu
        br        x0                /* branch to the given address */
master_cpu:
        /* On the master CPU */
#endif /* CONFIG_ARMV8_MULTIENTRY */
        bl        _main
主要做如下事情：
1 ） reset SCTRL 寄存器
具體可參考 reset_sctrl 函數(shù)，由 CONFIG_SYS_RESET_SCTRL 控制，一般不需要打開。該配置項(xiàng)的解釋如下：
Reset the SCTRL register at the very beginning of execution to avoid interference from stale mappings set up by early firmware/loaders/etc.
2 ）根據(jù)當(dāng)前的 EL 級(jí)別，配置中斷向量、 MMU 、 Endian 、 i/d Cache 等。
3 ）配置 ARM 的勘誤表
具體可參考 apply_core_errata 函數(shù)，由 CONFIG_ARM_ERRATA_XXX 控制，在項(xiàng)目的初期，可以不打開，后續(xù)根據(jù)實(shí)際情況打開）。
4 ）調(diào)用 lowlevel_init
的功能解釋如下（具體可參考 u-boot的readme文檔）：
        - purpose: essential init to permit execution to reach board_init_f()
        - no global_data or BSS
        - there is no stack (ARMv7 may have one but it will soon be removed)
        - must not set up SDRAM or use console
        - must only do the bare minimum to allow execution to continue to
                board_init_f()
        - this is almost never needed
        - return normally from this function
一般情況下，不需要實(shí)現(xiàn)。 start.S中也有一個(gè) WEAK 類型的定義，由 CONFIG_GICV2 | CONFIG_GICV3 控制，一般情況下，沒有打開的必要。
5 ）如果是多 CPU 的場(chǎng)景，處理其它的 CPU 的 boot
多 CPU 功能由 CONFIG_ARMV8_MULTIENTRY 控制，不需要打開。
6 ）跳轉(zhuǎn)到 arm 公共的 _main 中執(zhí)行
ARM64 平臺(tái)的 _main 位于 crt0_64.S文件中，具體請(qǐng)參考下面的描述。
3 _main
crt0 是 C-runtime Startup Code 的簡(jiǎn)稱，意思就是運(yùn)行 C 代碼之前的準(zhǔn)備工作。關(guān)于 _main 函數(shù)， crt0_64.S中有非常詳細(xì)的注釋（這一點(diǎn)要給 u-boot 點(diǎn) 100 個(gè)贊?。?，大家可以參考。該函數(shù)的定義如下：
ENTRY(_main)
/*
* Set up initial C runtime environment and call board_init_f(0).
*/
#if defined(CONFIG_SPL_BUILD) && defined(CONFIG_SPL_STACK)
        ldr        x0, =(CONFIG_SPL_STACK)
#else
        ldr        x0, =(CONFIG_SYS_INIT_SP_ADDR)
#endif
        bic        sp, x0, #0xf/* 16-byte alignment for ABI compliance */
        mov        x0, sp
        bl        board_init_f_alloc_reserve
        mov        sp, x0
        /* set up gd here, outside any C code */
        mov        x18, x0
        bl        board_init_f_init_reserve
        mov        x0, #0
        bl        board_init_f
#if !defined(CONFIG_SPL_BUILD)
/*
* Set up intermediate environment (new sp and gd) and call
* relocate_code(addr_moni). Trick here is that we'll return
* 'here' but relocated.
*/
        ldr        x0, [x18, #GD_START_ADDR_SP]/* x0 <- gd-="">start_addr_sp */
        bic        sp, x0, #0xf/* 16-byte alignment for ABI compliance */
        ldr        x18, [x18, #GD_BD]                /* x18 <- gd-="">bd */
        sub        x18, x18, #GD_SIZE                /* new GD is below bd */
        adr        lr, relocation_return
        ldr        x9, [x18, #GD_RELOC_OFF]        /* x9 <- gd-="">reloc_off */
        add        lr, lr, x9/* new return address after relocation */
        ldr        x0, [x18, #GD_RELOCADDR]        /* x0 <- gd-="">relocaddr */
        b        relocate_code
relocation_return:
/*
* Set up final (full) environment
*/
        bl        c_runtime_cpu_setup        /* still call old routine */
/* TODO: For SPL, call spl_relocate_stack_gd() to alloc stack relocation */
/*
* Clear BSS section
*/
        ldr        x0, =__bss_start        /* this is auto-relocated! */
        ldr        x1, =__bss_end        /* this is auto-relocated! */
        mov        x2, #0
clear_loop:
        str        x2, [x0]
        add        x0, x0, #8
        cmp        x0, x1
        b.lo        clear_loop
        /* call board_init_r(gd_t *id, ulong dest_addr) */
        mov        x0, x18                        /* gd_t */
        ldr        x1, [x18, #GD_RELOCADDR]        /* dest_addr */
        b        board_init_r                /* PC relative jump */
        /* NOTREACHED - board_init_r() does not return */
#endif /* !CONFIG_SPL_BUILD */
ENDPROC(_main)
功能可總結(jié)為（大部分翻譯自 crt0_64.S中的注釋）：
1 ）設(shè)置 C 代碼的運(yùn)行環(huán)境，為調(diào)用 board_init_f 接口做準(zhǔn)備。包括：
a ）設(shè)置堆棧（ C 代碼的函數(shù)調(diào)用，堆棧是必須的）。如果當(dāng)前的編譯是 SPL （由 CONFIG_SPL_BUILD 定義），可單獨(dú)定義堆?；罚?/span> CONFIG_SPL_STACK ），否則，通過 CONFIG_SYS_INIT_SP_ADDR 定義堆棧基址。
b ）調(diào)用 board_init_f_alloc_reserve接口，從堆棧開始的地方，為 u-boot 中大名鼎鼎的 GD ('global data')  數(shù)據(jù)結(jié)構(gòu)，分配空間。
c ）調(diào)用 board_init_f_init_reserve接口，對(duì) GD 進(jìn)行初始化。
2 ）調(diào)用 board_init_f 函數(shù)，完成一些前期的初始化工作，例如：
a ）點(diǎn)亮一個(gè) Debug 用的 LED 燈，表示 u-boot 已經(jīng)活了。
b ）初始化 DRAM 、 DDR 等 system 范圍的 RAM 等。
c ）計(jì)算后續(xù)代碼需要使用的一些參數(shù)，包括 relocation destination 、 the future stack 、 the future GD location 等。
注 5 ：關(guān)于 u-boot 的 relocation 操作，后續(xù)會(huì)有專門的文章介紹。
3 ）如果當(dāng)前是 SPL （由 CONFIG_SPL_BUILD 控制），則 _main 函數(shù)結(jié)束，直接返回。如果是正常的 u-boot ，則繼續(xù)執(zhí)行后續(xù)的動(dòng)作。
4 ）根據(jù) board_init_f 指定的參數(shù)，執(zhí)行 u-boot 的 relocation 操作。
5 ）清除 BBS 段。
6 ）調(diào)用 board_init_r函數(shù)，執(zhí)行后續(xù)的初始化操作（已經(jīng)不再本文的討論范圍了，具體請(qǐng)參考后續(xù)的分析文章）。
總結(jié)1 SPL功能
SPL 是 Secondary Program Loader 的簡(jiǎn)稱，之所以稱作 secondary ，是相對(duì)于 ROM code 來說的。 SPL 是 u-boot 中獨(dú)立的一個(gè)代碼分支，由 CONFIG_SPL_BUILD 配置項(xiàng)控制，是為了在正常的 u-boot image 之外，提供一個(gè)獨(dú)立的、小 size 的 SPL image ，通常用于那些 SRAM 比較?。ɑ蛘咂渌拗疲o法直接裝載并運(yùn)行整個(gè) u-boot 的平臺(tái)。
如果使用了 SPL 功能， u-boot 的啟動(dòng)流程通常是：
ROM code 加載 SPL 并運(yùn)行；
SPL 進(jìn)行必要的初始化之后，加載 u-boot 并運(yùn)行；
u-boot 進(jìn)行后續(xù)的操作。
因此，如果使用 SPL 功能，需要盡可能的減少 SPL 的代碼量，以減小它的 size 。
2 配置項(xiàng)總結(jié)
經(jīng)過第 3 章的流程分析，我們可以總結(jié)出和 “ 平臺(tái)相關(guān)部分的啟動(dòng)流程 ” 有關(guān)的配置項(xiàng)，記錄如下：
CONFIG_SYS_RESET_SCTRL ，控制是否在啟動(dòng)的時(shí)候 reset SCTRL 寄存器，一般不需要打開；
CONFIG_ARM_ERRATA_XXX ，控制 ARM core 的勘誤信息，一般不需要打開；
CONFIG_GICV2 、 CONFIG_GICV3 ，控制 GIC 的版本，用到的時(shí)候再說明；
CONFIG_ARMV8_MULTIENTRY ，控制是否在 u-boot 中使用多 CPU ，一般不需要；
CONFIG_SPL_BUILD ，是否是能 SPL 的編譯，需要的話可以打開；
CONFIG_SPL_STACK ，如果配置了 CONFIG_SPL_BUILD ，是否為 SPL image 配置單獨(dú)的 stack （ SP 基址），如果需要，通過該配置項(xiàng)配置，如果不需要，則使用 CONFIG_SYS_INIT_SP_ADDR ；
CONFIG_SYS_INIT_SP_ADDR ，配置 u-boot 的 stack （ SP 基址），對(duì)于 u-boot 功能來說，必須提供。
原文來自：蝸窩科技
您還未登錄，請(qǐng)先登錄

熱門帖子

最新帖子

?